Всем добрый день.
Коллеги, если есть, поделитесь рабочим кодом отправки файла в MAX, прости господи.

(0) https://infostart.ru/1c/reports/2627007/
https://infostart.ru/1c/tools/2628963/

(1) я так понимаю, что оба решения через GREEN-API. Так я умею. Напрямую через MAX API надо

(2) https://dev.max.ru/docs-api/methods/POST/uploads

(3) вот как раз по этой документации и пытаюсь сделать. Ссылку на загрузку получаю.
Дальше надо загрузить файл.
curl -X POST \
  -H "Content-Type: multipart/form-data" \
  -F "data=@movie.mp4" \
  "https://vu.mycdn.me/upload.do?sig={signature}&expires={timestamp}"

Что такое signature, что туда передавать?

(4) случаем это не ЭЦП (точнее отпечаток-сигнатура файла) по ГОСТ через КриптоПРО?
https://xn----7sbmxacaqnu.xn--p1ai/news/kak_sozdat_sig_fajl_s%20pomoshchyu_kriptopro/

(4) Эти параметры уже должны быть в ссылке на загрузку

(6) дык это же загрузка файла видео в CDN от ВК
требуют указать криптохэш и время жизни файла видео

(7)+ в ответ на загрузку вернется ссылка на видео, которую можно вставить в сообщение

(4) Удалось направить файл и получить Токен вложения?
(8) Непонятно как его туда нормально загнать, пример бы

Это не работает
ДвоичныеДанныеФайла = Новый ДвоичныеДанные(ПутьКФайлу);
Файлы = Новый Массив;
Файлы.Добавить(Новый Структура("Имя, Данные, ИмяФайла", "data", ДвоичныеДанныеФайла, "1.txt"));
Результат = Коннектор.Post(ПутьДляЗагрузкиФайла, , Новый Структура("Файлы", Файлы));

Есть подозрение что нужно использовать Сжатие GZip
Т.к. ответ приходит уже сжатый, а первые значения 1F 8B

Забыл отписаться. Исправляю упущение.
Рабочая процедура отправки файла в MAX.
ПутьКФайлу - путь к файлу во временном хранилище
IDЧата - это user_id пользователя
ТокенБота - токен бота

Чтобы отправлять не конкретному пользователю, а в группу, надо в этой стоке заменить user_id на chat_id
HTTPЗапросСообщения = Новый HTTPЗапрос("/messages?user_id=" + IDЧата, ЗаголовкиАвторизации);

Процедура ОтправитьФайлВMax(ПутьКФайлу, IDЧата, ТокенБота, ТипФайла = "file", ТекстСообщения = "") Экспорт
      ИмяФайла     = "ФайлОтчета_" + СтрЗаменить(ТекущаяДата(),":","") + ".xls";
      // Заголовки авторизации
      ЗаголовкиАвторизации = Новый Соответствие;
      ЗаголовкиАвторизации.Вставить("Authorization", ТокенБота);

      //Получаем URL для загрузки файла
      HTTPСоединение = Новый HTTPСоединение("platform-api.max.ru", 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
      HTTPЗапрос = Новый HTTPЗапрос("/uploads?type=file", ЗаголовкиАвторизации);
      
      // Отправляем POST запрос (пустое тело)
      HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
      Если HTTPОтвет.КодСостояния <> 200 Тогда
          ВызватьИсключение "Ошибка при получении URL для загрузки: " + HTTPОтвет.КодСостояния + " - " + HTTPОтвет.ПолучитьТелоКакСтроку();
      КонецЕсли;
      
      // Парсим JSON ответ
      ЧтениеJSON = Новый ЧтениеJSON;
      ЧтениеJSON.УстановитьСтроку(HTTPОтвет.ПолучитьТелоКакСтроку());
      ОтветМетаЗагрузки = ПрочитатьJSON(ЧтениеJSON);
      ЧтениеJSON.Закрыть();
      
      URLДляЗагрузки = ОтветМетаЗагрузки.url; // URL куда слать файл

      //Загружаем файл на полученный URL (Multipart/Form-Data)

      // Разбираем URL чтобы понять куда коннектиться
      РазборURL = СтрРазделить(URLДляЗагрузки, "/", Ложь);
      СерверЗагрузки = РазборURL[1]; // Например, storage.max.ru
      ПутьЗагрузки   = СтрЗаменить("/" + СтрСоединить(РазборURL, "/"),"/https:/fu.oneme.ru",""); // Остальная часть пути
      
      
      // Формируем Multipart тело запроса
      Boundary      = "----WebKitFormBoundary" + СтрЗаменить(Новый UUID, "-", "");
      ДвоичныеДанныеФайла = Новый ДвоичныеДанные(ПутьКФайлу);
      
      // Строим тело запроса в памяти
      ПотокВПамяти = Новый ПотокВПамяти;
      ЗаписьДанных = Новый ЗаписьДанных(ПотокВПамяти);
      
      //Начало части (headers)
      ЗаписьДанных.ЗаписатьСтроку("--" + Boundary);
      ЗаписьДанных.ЗаписатьСтроку("Content-Disposition: form-data; name=""data""; filename=""" + ИмяФайла + """");
      ЗаписьДанных.ЗаписатьСтроку("Content-Type: application/octet-stream");
      ЗаписьДанных.ЗаписатьСтроку(""); // Пустая строка между заголовками и данными
      
      //Сам файл (бинарные данные)
      ЗаписьДанных.Записать(ДвоичныеДанныеФайла);
      ЗаписьДанных.ЗаписатьСтроку(""); // Перенос строки после файла
      
      //Конец запроса
      ЗаписьДанных.ЗаписатьСтроку("--" + Boundary + "--");
      
      ЗаписьДанных.Закрыть();
      ТелоЗапросаЗагрузки = ПотокВПамяти.ЗакрытьИПолучитьДвоичныеДанные();
      
      // Формируем HTTP запрос
      HTTPСоединениеЗагрузки = Новый HTTPСоединение(СерверЗагрузки, 443, , , , , Новый ЗащищенноеСоединениеOpenSSL());
      HTTPЗапросЗагрузки = Новый HTTPЗапрос(ПутьЗагрузки);
      HTTPЗапросЗагрузки.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary=" + Boundary);
      HTTPЗапросЗагрузки.УстановитьТелоИзДвоичныхДанных(ТелоЗапросаЗагрузки);
      
      HTTPОтветЗагрузки = HTTPСоединениеЗагрузки.ОтправитьДляОбработки(HTTPЗапросЗагрузки);
      
      Если HTTPОтветЗагрузки.КодСостояния <> 200 Тогда
          ВызватьИсключение "Ошибка при загрузке файла: " + HTTPОтветЗагрузки.КодСостояния;
      КонецЕсли;
      
      // Парсим ответ загрузки (информация о файле)
      ЧтениеJSON.УстановитьСтроку(HTTPОтветЗагрузки.ПолучитьТелоКакСтроку());
      ДанныеФайла = ПрочитатьJSON(ЧтениеJSON);
      ЧтениеJSON.Закрыть();

         //тут нужна пауза, видимо файл не успевает записаться. Без паузы валит ошибку
     //Ошибка отправки сообщения: {"code":"attachment.not.ready","message":"Key: errors.process.attachment.file.not.processed"}      
     //с паузой всё норм
      ДатаКон = ТекущаяДата() + 1;//1 секундой больше
      Пока ТекущаяДата() < ДатаКон Цикл
      КонецЦикла;      
      
      //ВызватьПаузу(1000);

      //Отправляем сообщение с вложением
      HTTPЗапросСообщения = Новый HTTPЗапрос("/messages?user_id=" + IDЧата, ЗаголовкиАвторизации);
      HTTPЗапросСообщения.Заголовки.Вставить("Content-Type", "application/json");
      
      // Формируем JSON тело
      ЗаписьJSON = Новый ЗаписьJSON;
      ЗаписьJSON.УстановитьСтроку();
      ЗаписьJSON.ЗаписатьНачалоОбъекта();
      ЗаписьJSON.ЗаписатьИмяСвойства("text");
      ЗаписьJSON.ЗаписатьЗначение("Отправляю файл");
      
      ЗаписьJSON.ЗаписатьИмяСвойства("attachments");
      ЗаписьJSON.ЗаписатьНачалоМассива();
      ЗаписьJSON.ЗаписатьНачалоОбъекта();
      ЗаписьJSON.ЗаписатьИмяСвойства("type");
      ЗаписьJSON.ЗаписатьЗначение("file");
      
      // В payload записываем весь объект, полученный на шаге 2
      ЗаписьJSON.ЗаписатьИмяСвойства("payload");
      ЗаписатьJSON(ЗаписьJSON, ДанныеФайла);
      ЗаписьJSON.ЗаписатьКонецОбъекта();
      ЗаписьJSON.ЗаписатьКонецМассива();
      ЗаписьJSON.ЗаписатьКонецОбъекта();
      
      СтрокаТелаЗапроса = ЗаписьJSON.Закрыть();
      HTTPЗапросСообщения.УстановитьТелоИзСтроки(СтрокаТелаЗапроса, КодировкаТекста.UTF8, ИспользованиеByteOrderMark.НеИспользовать);
      
      HTTPОтветСообщения = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапросСообщения);
      
      Если HTTPОтветСообщения.КодСостояния = 200 Тогда
          Сообщить("Файл успешно отправлен!");
      Иначе
          Сообщить("Ошибка отправки сообщения: " + HTTPОтветСообщения.ПолучитьТелоКакСтроку());
      КонецЕсли;
  
КонецПроцедуры

Пригодится.

(13) Спасибки. А вдруг тоже придется прикоснуться к прекрасному :-(

Пользуясь случаем спрошу кто работает с макс. Как в групповом чате через api упомянуть пользователя?
В телеграмм было через ИмяПользователя, а тут не выходит

(14) вот так
{
  "text": "Юрий <a href=\"max://user/123456789\">Юрий</a>",
  "format": "html"
}

бот, который отправляет сообщение, должен быть админом чата. Иначе ссылка не обработается

(15) в html никак не выходит.
вот в markdown нормально уходит: [Юрий](max://user/123456789)


"text": "[Имя Фамилия](max://user/user_id)", "format": "markdown"
Вместо User mention указывайте полное имя пользователя из профиля в MAX, в том числе фамилию. Если фамилия отсутствует — только имя

(16) да, так тоже отработал
{
  "text": "[Юрий](max://user/12345678)",
  "format": "markdown"
}

но и в html работает

(15) Забавно. Если бот не админ чата - он сможет писать в чат, но не не сможет его читать. Нигде в API об этом не написано и ты битый час сидишь и не понимаешь, почему /updates отваливается по таймауту и никаких сообщений из группы ты там не увидишь.

(18) там вся документация левой ногой написана. Но, надо отдать должное, на вопросы отвечают довольно оперативно.